path: root/indra/newview/app_settings/shaders/class1/deferred/materialF.glsl

/** 
 * @file materialF.glsl
 *
 * $LicenseInfo:firstyear=2007&license=viewerlgpl$
 * Second Life Viewer Source Code
 * Copyright (C) 2007, Linden Research, Inc.
 * 
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation;
 * version 2.1 of the License only.
 * 
 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 * Lesser General Public License for more details.
 * 
 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
 * 
 * Linden Research, Inc., 945 Battery Street, San Francisco, CA  94111  USA
 * $/LicenseInfo$
 */
 
/*[EXTRA_CODE_HERE]*/

#define DIFFUSE_ALPHA_MODE_IGNORE   0
#define DIFFUSE_ALPHA_MODE_BLEND    1
#define DIFFUSE_ALPHA_MODE_MASK     2
#define DIFFUSE_ALPHA_MODE_EMISSIVE 3

uniform float emissive_brightness;
uniform float display_gamma;
uniform int sun_up_factor;

#ifdef WATER_FOG
vec4 applyWaterFogView(vec3 pos, vec4 color);
#endif

vec3 atmosFragLighting(vec3 l, vec3 additive, vec3 atten);
vec3 scaleSoftClipFrag(vec3 l);

#if defined(VERT_ATMOSPHERICS)
vec3 getSunlitColor();
vec3 getAmblitColor();
vec3 getAdditiveColor();
vec3 getAtmosAttenuation();
#else
void calcFragAtmospherics(vec3 inPositionEye, float ambFactor, out vec3 sunlit, out vec3 amblit, out vec3 additive, out vec3 atten);
#endif

vec3 srgb_to_linear(vec3 cs);
vec3 linear_to_srgb(vec3 cs);

#if (DIFFUSE_ALPHA_MODE == DIFFUSE_ALPHA_MODE_BLEND)

#ifdef DEFINE_GL_FRAGCOLOR
out vec4 frag_color;
#else
#define frag_color gl_FragColor
#endif

float sampleDirectionalShadow(vec3 pos, vec3 norm, vec2 pos_screen);

uniform samplerCube environmentMap;
uniform sampler2D     lightFunc;

// Inputs
uniform vec4 morphFactor;
uniform vec3 camPosLocal;
//uniform vec4 camPosWorld;
uniform vec4 gamma;
uniform mat3 env_mat;
uniform mat3 ssao_effect_mat;

uniform vec3 sun_dir;
uniform vec3 moon_dir;
VARYING vec2 vary_fragcoord;

VARYING vec3 vary_position;

uniform mat4 inv_proj;
uniform vec2 screen_res;

uniform vec4 light_position[8];
uniform vec3 light_direction[8];
uniform vec4 light_attenuation[8]; 
uniform vec3 light_diffuse[8];

vec3 calcPointLightOrSpotLight(vec3 light_col, vec3 npos, vec3 diffuse, vec4 spec, vec3 v, vec3 n, vec4 lp, vec3 ln, float la, float fa, float is_pointlight, inout float glare, float ambiance, float shadow)
{
    //get light vector
    vec3 lv = lp.xyz-v;
    
    //get distance
    float d = length(lv);
    
    float da = 1.0;

    vec3 col = vec3(0,0,0);

    if (d > 0.0 && la > 0.0 && fa > 0.0)
    {
        //normalize light vector
        lv = normalize(lv);
    
        //distance attenuation
        float dist = d/la;
        float dist_atten = clamp(1.0-(dist-1.0*(1.0-fa))/fa, 0.0, 1.0);
        dist_atten *= dist_atten;
        
        // spotlight coefficient.
        float spot = max(dot(-ln, lv), is_pointlight);
        da *= spot*spot; // GL_SPOT_EXPONENT=2

        //angular attenuation
        da = dot(n, lv);
        da *= clamp(da, 0.0, 1.0);
        da *= pow(da, 1.0 / 1.3);
        
        float lit = max(da * dist_atten, 0.0);

        col = light_col*lit*diffuse;

        float amb_da = ambiance;
        amb_da *= dist_atten;
        amb_da += (da*0.5) * ambiance;
        amb_da += (da*da*0.5 + 0.25) * ambiance;
        amb_da = min(amb_da, 1.0f - lit);

        col.rgb += amb_da * light_col * diffuse;

        if (spec.a > 0.0)
        {
            //vec3 ref = dot(pos+lv, norm);
            vec3 h = normalize(lv+npos);
            float nh = dot(n, h);
            float nv = dot(n, npos);
            float vh = dot(npos, h);
            float sa = nh;
            float fres = pow(1 - dot(h, npos), 5)*0.4+0.5;

            float gtdenom = 2 * nh;
            float gt = max(0, min(gtdenom * nv / vh, gtdenom * da / vh));
                                
            if (nh > 0.0)
            {
                float scol = fres*texture2D(lightFunc, vec2(nh, spec.a)).r*gt/(nh*da);
                vec3 speccol = lit*scol*light_col.rgb*spec.rgb;
                col += speccol;

                float cur_glare = max(speccol.r, speccol.g);
                cur_glare = max(cur_glare, speccol.b);
                glare = max(glare, speccol.r);
                glare += max(cur_glare, 0.0);
            }
        }
    }

    return max(col, vec3(0.0,0.0,0.0)); 

}

#else
#ifdef DEFINE_GL_FRAGCOLOR
out vec4 frag_data[3];
#else
#define frag_data gl_FragData
#endif
#endif

uniform sampler2D diffuseMap;

#if HAS_NORMAL_MAP
uniform sampler2D bumpMap;
#endif

#if HAS_SPECULAR_MAP
uniform sampler2D specularMap;

VARYING vec2 vary_texcoord2;
#endif

uniform float env_intensity;
uniform vec4 specular_color;  // specular color RGB and specular exponent (glossiness) in alpha

#if (DIFFUSE_ALPHA_MODE == DIFFUSE_ALPHA_MODE_MASK)
uniform float minimum_alpha;
#endif

#if HAS_NORMAL_MAP
VARYING vec3 vary_mat0;
VARYING vec3 vary_mat1;
VARYING vec3 vary_mat2;
VARYING vec2 vary_texcoord1;
#else
VARYING vec3 vary_normal;
#endif

VARYING vec4 vertex_color;
VARYING vec2 vary_texcoord0;

vec2 encode_normal(vec3 n);

void main() 
{
    vec2 pos_screen = vary_texcoord0.xy;

    vec4 diffcol = texture2D(diffuseMap, vary_texcoord0.xy);
    diffcol.rgb *= vertex_color.rgb;

#if (DIFFUSE_ALPHA_MODE == DIFFUSE_ALPHA_MODE_MASK)
    if (diffcol.a < minimum_alpha)
    {
        discard;
    }
#endif

#if (DIFFUSE_ALPHA_MODE == DIFFUSE_ALPHA_MODE_BLEND)
    vec3 gamma_diff = diffcol.rgb;
#endif

#if HAS_SPECULAR_MAP
    vec4 spec = texture2D(specularMap, vary_texcoord2.xy);
    spec.rgb *= specular_color.rgb;
#else
    vec4 spec = vec4(specular_color.rgb, 1.0);
#endif

#if HAS_NORMAL_MAP
    vec4 norm = texture2D(bumpMap, vary_texcoord1.xy);

    norm.xyz = norm.xyz * 2 - 1;

    vec3 tnorm = vec3(dot(norm.xyz,vary_mat0),
              dot(norm.xyz,vary_mat1),
              dot(norm.xyz,vary_mat2));
#else
    vec4 norm = vec4(0,0,0,1.0);
    vec3 tnorm = vary_normal;
#endif

    norm.xyz = tnorm;
    norm.xyz = normalize(norm.xyz);

    vec2 abnormal   = encode_normal(norm.xyz);

    vec4 final_color = diffcol;
    
#if (DIFFUSE_ALPHA_MODE != DIFFUSE_ALPHA_MODE_EMISSIVE)
    final_color.a = emissive_brightness;
#else
    final_color.a = max(final_color.a, emissive_brightness);
#endif

    vec4 final_specular = spec;
#if HAS_SPECULAR_MAP
    vec4 final_normal = vec4(encode_normal(normalize(tnorm)), env_intensity * spec.a, 0.0);
    final_specular.a = specular_color.a * norm.a;
#else
    vec4 final_normal = vec4(encode_normal(normalize(tnorm)), env_intensity, 0.0);
    final_specular.a = specular_color.a;
#endif
    

#if (DIFFUSE_ALPHA_MODE == DIFFUSE_ALPHA_MODE_BLEND)
        //forward rendering, output just lit RGBA
    vec3 pos = vary_position;

    float shadow = sampleDirectionalShadow(pos.xyz, norm.xyz, pos_screen);

    spec = final_specular;
    vec4 diffuse = final_color;

    diffuse.rgb = srgb_to_linear(diffuse.rgb);

    float envIntensity = final_normal.z;

    vec3 col = vec3(0.0f,0.0f,0.0f);

    float bloom = 0.0;
    vec3 sunlit;
    vec3 amblit;
    vec3 additive;
    vec3 atten;

#if defined(VERT_ATMOSPHERICS)
    sunlit   = getSunlitColor();
    amblit   = getAmblitColor();
    additive = getAdditiveColor();
    atten    = getAtmosAttenuation();
#else
    calcFragAtmospherics(pos.xyz, 1.0, sunlit, amblit, additive, atten);
#endif

    vec3 refnormpersp = normalize(reflect(pos.xyz, norm.xyz));

    vec3 light_dir = (sun_up_factor == 1) ? sun_dir : moon_dir;

    float da = dot(norm.xyz, light_dir.xyz);
    da = clamp(da, 0.0, 1.0);
    da = pow(da, 1.0 / 1.3);

    col.rgb = amblit;
    
    float ambient = abs(da);
    ambient *= 0.5;
    ambient *= ambient;
    ambient = 1.0 - ambient * smoothstep(0.0, 0.3, shadow);

    vec3 sun_contrib = min(da, shadow) * sunlit;
   
    col.rgb *= ambient;
    col.rgb += sun_contrib;
    col.rgb *= diffuse.rgb;
 
    float glare = 0.0;

    if (spec.a > 0.0) // specular reflection
    {
        // the old infinite-sky shiny reflection
        //
                
        float sa = dot(refnormpersp, sun_dir.xyz);

        vec3 dumbshiny = sunlit*shadow*(texture2D(lightFunc, vec2(sa, spec.a)).r);
                            
        // add the two types of shiny together
        vec3 spec_contrib = dumbshiny * spec.rgb;
        bloom = dot(spec_contrib, spec_contrib) / 6;

        glare = max(spec_contrib.r, spec_contrib.g);
        glare = max(glare, spec_contrib.b);

        col += spec_contrib;
    }

vec3 post_spec = col.rgb;

    col = mix(col.rgb, diffuse.rgb, diffuse.a);

    if (envIntensity > 0.0)
    {
        //add environmentmap
        vec3 env_vec = env_mat * refnormpersp;
        
        vec3 refcol = textureCube(environmentMap, env_vec).rgb;

        col = mix(col.rgb, refcol, 
            envIntensity);  

        float cur_glare = max(refcol.r, refcol.g);
        cur_glare = max(cur_glare, refcol.b);
        cur_glare *= envIntensity*4.0;
        glare += cur_glare;
    }

    col = atmosFragLighting(col, additive, atten);
    col = scaleSoftClipFrag(col);

vec3 post_atmo= col.rgb;

    vec3 npos = normalize(-pos.xyz);
            
    vec3 light = vec3(0,0,0);

 #define LIGHT_LOOP(i) light.rgb += calcPointLightOrSpotLight(light_diffuse[i].rgb, npos, diffuse.rgb, final_specular, pos.xyz, norm.xyz, light_position[i], light_direction[i].xyz, light_attenuation[i].x, light_attenuation[i].y, light_attenuation[i].z, glare, light_attenuation[i].w, shadow);

        LIGHT_LOOP(1)
        LIGHT_LOOP(2)
        LIGHT_LOOP(3)
        LIGHT_LOOP(4)
        LIGHT_LOOP(5)
        LIGHT_LOOP(6)
        LIGHT_LOOP(7)

    col.rgb += light.rgb;

vec3 post_lighting = col.rgb;

    glare = min(glare, 1.0);
    float al = max(diffcol.a,glare)*vertex_color.a;

#ifdef WATER_FOG
    vec4 temp = applyWaterFogView(pos, vec4(col.rgb, al));
    col.rgb = temp.rgb;
    al = temp.a;
#endif

    col.rgb = linear_to_srgb(col.rgb);

    frag_color.rgb = col.rgb;
    frag_color.a   = al;

#else
    frag_data[0] = final_color;
    frag_data[1] = final_specular; // XYZ = Specular color. W = Specular exponent.
    frag_data[2] = final_normal; // XY = Normal.  Z = Env. intensity.
#endif
}